Respuesta a la acusación de Checkpoint Research sobre nuestra empresa
BreakingSecurity.net
Producto Ha sido agregado a tu carro.

Sincronización de reloj

Mantenga su reloj de Windows sincronizado.

Sincronización de reloj es un sencillo script de línea de comandos para mantener sincronizado el reloj de Windows.
En algunos sistemas y por diferentes causas, el reloj de Windows puede desincronizarse con frecuencia.
Esta pequeña herramienta debería resolver este problema.
ClockSync está escrito en lenguaje por lotes.

Si está buscando un programa para mantener la hora precisa de su sistema, ¡lo acaba de encontrar!

  • Gratuito
  • Open Source
  • Pequeño: menos de 2 kb
  • Rápido y fácil de usar
  • Funciona en cualquier Windows desde Win7 hasta Win10, incluidas las ediciones de servidor.
    Se admiten los sistemas operativos de 32 y 64 bits.
Uso:
  1. Asegúrate de estar conectado a Internet.
  2. Ejecute el archivo ClockSync.bat con privilegios de administrador.

ClockSync realizará automáticamente una primera sincronización.
Después de eso, realiza sincronizaciones periódicas en un intervalo de tiempo.
Por defecto sincroniza la hora cada 10 minutos.

Si desea especificar un intervalo de resincronización personalizado, ejecute el archivo con un parámetro de comando "minutos".
El siguiente comando, por ejemplo, sincroniza el reloj cada 60 minutos:
“RelojSync.bat 60”

Detalles:

ClockSync mantendrá la precisión del reloj de su sistema mediante la realización de sincronizaciones periódicas con su servidor de hora de Internet predeterminado.

Si el servicio de hora de Windows o la sincronización de hora de Internet estaban deshabilitados, ClockSync los reiniciará.
Esto ayudará a mantener la precisión del reloj de su sistema incluso cuando ClockSync no se esté ejecutando.

Descargar "ClockSync" ClockSync.zip – Descargado 1018 veces – 900 B

Archivo ClockSync.bat

Código fuente:

ClockSync.bat:

@echo off
echo * ClockSync v1.0
echo * BreakingSecurity.net
echo.
:: Check that we own administrator access level. 
echo [INFO] Checking Access Level...
net session >nul 2>&1
if %errorLevel% == 0 (
	:: We have the necessary rights, go forward
	echo [INFO] Administrative Access confirmed.
) else (
	:: Error, insufficient privileges. Exit program.
	echo [ERROR] Insufficient Access Level. Please restart script with administrative permission.
	echo.
	echo Press any key to exit...
	pause > nul
	exit
)
:: Check command-line parameter.
:: User can specify any number of minutes for the Resync interval.
:: If there is no user-specified parameter, default one is used.
set /A minutes = 10
if not "%1" == "" (
	set /A minutes=%1
)
:loop
:: Synchronize Clock
:: Use /force parameter to bypass "time change too big" error
w32tm /resync /force
if not errorlevel 0 (
	:: If Error, restart time service
    echo [WARNING] Time Service error. Restarting service...
	net stop w32time
    w32tm /unregister
    w32tm /register
    net start w32time
	w32tm /resync /force
	if not errorlevel 0 (
		:: Unknown error, exit program.
		echo [ERROR] Unknown error.
		echo.
		echo Press any key to exit...
		pause > nul
		exit
	)
)
echo.
echo [SUCCESS] Clock successfully synchronized!
echo Date: %date%
echo Time: %time%
echo.
:: Sleep
set /A seconds = %minutes% * 60
echo [INFO] Sleeping for %minutes% minutes until next synchronization...
echo.
ping 127.0.0.1 -n %seconds% > nul
:: Repeat
goto loop
Menu