Synchronisation d'horloge | BreakingSecurity.net

ClockSync

Gardez votre horloge Windows synchronisée.

ClockSync est un simple script de ligne de commande pour garder votre horloge Windows synchronisée.
Dans certains systèmes et pour différentes causes, l'horloge Windows peut souvent se désynchroniser.
Ce petit outil devrait résoudre ce problème.
ClockSync est écrit en langage batch.

Si vous cherchez un programme pour garder l'heure de votre système exacte, vous venez de le trouver !

Gratuit
Open source
Petit : moins de 2 ko
Rapide et facile à utiliser
Fonctionne sur n'importe quel Windows de Win7 à Win10, y compris les éditions Server.
Les systèmes d'exploitation 32 bits et 64 bits sont pris en charge.

Usage:

Assurez-vous que vous êtes connecté à Internet.
Exécutez le fichier ClockSync.bat avec des privilèges d'administrateur.

ClockSync effectuera automatiquement une première synchronisation.
Après cela, il effectue des synchronisations périodiques sur un intervalle de temps.
Par défaut, il synchronise l'heure toutes les 10 minutes.

Si vous souhaitez spécifier un intervalle de resynchronisation personnalisé, exécutez le fichier avec un paramètre de commande "minutes".
La commande suivante, par exemple, synchronise l'horloge toutes les 60 minutes :
"ClockSync.bat 60"

Détails:

ClockSync maintiendra la précision de l'horloge de votre système en effectuant des synchronisations périodiques avec votre serveur de temps Internet par défaut.

Si le service de temps Windows ou la synchronisation de l'heure Internet ont été désactivés, ClockSync les redémarrera.
Cela aidera à garder votre horloge système précise même lorsque ClockSync n'est pas en cours d'exécution.

Télécharger "ClockSync" ClockSync.zip – Téléchargé 889 fois – 900 B

Fichier ClockSync.bat

Code source:

ClockSync.bat :

@echo off
echo * ClockSync v1.0
echo * BreakingSecurity.net
echo.
:: Check that we own administrator access level. 
echo [INFO] Checking Access Level...
net session >nul 2>&1
if %errorLevel% == 0 (
	:: We have the necessary rights, go forward
	echo [INFO] Administrative Access confirmed.
) else (
	:: Error, insufficient privileges. Exit program.
	echo [ERROR] Insufficient Access Level. Please restart script with administrative permission.
	echo.
	echo Press any key to exit...
	pause > nul
	exit
)
:: Check command-line parameter.
:: User can specify any number of minutes for the Resync interval.
:: If there is no user-specified parameter, default one is used.
set /A minutes = 10
if not "%1" == "" (
	set /A minutes=%1
)
:loop
:: Synchronize Clock
:: Use /force parameter to bypass "time change too big" error
w32tm /resync /force
if not errorlevel 0 (
	:: If Error, restart time service
    echo [WARNING] Time Service error. Restarting service...
	net stop w32time
    w32tm /unregister
    w32tm /register
    net start w32time
	w32tm /resync /force
	if not errorlevel 0 (
		:: Unknown error, exit program.
		echo [ERROR] Unknown error.
		echo.
		echo Press any key to exit...
		pause > nul
		exit
	)
)
echo.
echo [SUCCESS] Clock successfully synchronized!
echo Date: %date%
echo Time: %time%
echo.
:: Sleep
set /A seconds = %minutes% * 60
echo [INFO] Sleeping for %minutes% minutes until next synchronization...
echo.
ping 127.0.0.1 -n %seconds% > nul
:: Repeat
goto loop