ClockSync

Keep your Windows Clock synchronized.

ClockSync is a simple command-line script to keep your Windows clock synchronized.
In some systems and for different causes, Windows clock can frequently go out of sync.
This small tool should solve this problem.
ClockSync is written in Batch language.

If you’re looking for a program to keep your system time accurate, you’ve just found it!

Free
Open Source
Small: less then 2 kb
Fast and Easy to use
Works on any Windows from Win7 up to Win10, including Server editions.
Both 32-bit and 64-bit OS are supported.

Usage:

Make sure you are connected to the Internet.
Run ClockSync.bat file with administrator privileges.

ClockSync will automatically perform a first synchronization.
After that, it performs periodic synchronizations on a time interval.
By default, it synchronizes time each 10 minutes.

If you want to specify a custom resync interval, run the file with a “minutes” command parameter.
The following command, for example, synchronizes the clock every 60 minutes:
“ClockSync.bat 60”

Details:

ClockSync will keep your system clock accurate by performing periodic synchronizations with your default Internet Time Server.

If the Windows Time Service or Internet Time Synchronization were disabled, ClockSync will restart them.
This will help keeping your system clock accurate even when ClockSync is not running.

Download “ClockSync” ClockSync.zip – Downloaded 1018 times – 900 B

ClockSync.bat file

Source Code:

ClockSync.bat :

@echo off
echo * ClockSync v1.0
echo * BreakingSecurity.net
echo.
:: Check that we own administrator access level. 
echo [INFO] Checking Access Level...
net session >nul 2>&1
if %errorLevel% == 0 (
	:: We have the necessary rights, go forward
	echo [INFO] Administrative Access confirmed.
) else (
	:: Error, insufficient privileges. Exit program.
	echo [ERROR] Insufficient Access Level. Please restart script with administrative permission.
	echo.
	echo Press any key to exit...
	pause > nul
	exit
)
:: Check command-line parameter.
:: User can specify any number of minutes for the Resync interval.
:: If there is no user-specified parameter, default one is used.
set /A minutes = 10
if not "%1" == "" (
	set /A minutes=%1
)
:loop
:: Synchronize Clock
:: Use /force parameter to bypass "time change too big" error
w32tm /resync /force
if not errorlevel 0 (
	:: If Error, restart time service
    echo [WARNING] Time Service error. Restarting service...
	net stop w32time
    w32tm /unregister
    w32tm /register
    net start w32time
	w32tm /resync /force
	if not errorlevel 0 (
		:: Unknown error, exit program.
		echo [ERROR] Unknown error.
		echo.
		echo Press any key to exit...
		pause > nul
		exit
	)
)
echo.
echo [SUCCESS] Clock successfully synchronized!
echo Date: %date%
echo Time: %time%
echo.
:: Sleep
set /A seconds = %minutes% * 60
echo [INFO] Sleeping for %minutes% minutes until next synchronization...
echo.
ping 127.0.0.1 -n %seconds% > nul
:: Repeat
goto loop